ASP中常用的22个FSO文件操作函数整理(2)

Function ReportFileStatus(FileName)
'//功能：判断文件是否存在
'//形参：文件名
'//返回值：成功为1，失败为-1
'//
Dim msg
msg = -1
If (fso.FileExists(FileName)) Then
msg = 1
Else
msg = -1
End If
ReportFileStatus = msg
End Function

Function ShowDatecreated(filespec)
'//功能：文件创建日期
'//形参：文件名
'//返回值：成功：文件创建日期，失败：-1
'//
Dim f
If ReportFileStatus(filespec) = 1 Then
Set f = fso.GetFile(filespec)
ShowDatecreated = f.Datecreated
Else
ShowDatecreated = -1
End if
End Function

Function GetAttributes(FileName)
'//功能：显示文件属性
'//形参：文件名
'//返回值：成功：文件属性，失败：-1
'//
Dim f,Str
If ReportFileStatus(FileName) = 1 Then
Set f = fso.GetFile(FileName)
select Case f.attributes
Case 0 Str="普通文件。没有设置任何属性。 "
Case 1 Str="只读文件。可读写。 "
Case 2 Str="隐藏文件。可读写。 "
Case 4 Str="系统文件。可读写。 "
Case 16 Str="文件夹或目录。只读。 "
Case 32 Str="上次备份后已更改的文件。可读写。 "
Case 1024 Str="链接或快捷方式。只读。 "
Case 2048 Str=" 压缩文件。只读。"
End select
GetAttributes = Str
Else
GetAttributes = -1
End if
End Function

'Response.Write ShowFileAccessInfo("文件路径")
Function ShowFileAccessInfo(FileName,InfoType)
'//功能：显示文件创建时信息
'//形参：文件名,信息类别
'// 1 -----创建时间
'// 2 -----上次访问时间
'// 3 -----上次修改时间
'// 4 -----文件路径
'// 5 -----文件名称
'// 6 -----文件类型
'// 7 -----文件大小
'// 8 -----父目录
'// 9 -----根目录
'//返回值：成功为文件创建时信息，失败：-1
'//
Dim f, s
If ReportFileStatus(FileName) = 1 then
Set f = fso.GetFile(FileName)
select Case InfoType
Case 1 s = f.Datecreated '// 1 -----创建时间
Case 2 s = f.DateLastAccessed '// 2 -----上次访问时间
Case 3 s = f.DateLastModified '// 3 -----上次修改时间
Case 4 s = f.Path '// 4-----文件路径
Case 5 s = f.Name '// 5 -----文件名称
Case 6 s = f.Type '// 6-----文件类型
Case 7 s = f.Size '// 7-----文件大小
Case 8 s = f.ParentFolder '// 8 -----父目录
Case 9 s = f.RootFolder '// 8 -----根目录
End select
ShowFileAccessInfo = s
ELse
ShowFileAccessInfo = -1
End if
End Function 

Function WriteTxtFile(FileName,TextStr,WriteORAppendType)
Const ForReading = 1, ForWriting = 2 , ForAppending = 8
Dim f, m
select Case WriteORAppendType
Case 1: '文件进行写操作
Set f = fso.OpenTextFile(FileName, ForWriting, True)
f.Write TextStr
f.Close
If ReportFileStatus(FileName) = 1 then
WriteTxtFile = 1
Else
WriteTxtFile = -1
End if
Case 2: '文件末尾进行写操作
If ReportFileStatus(FileName) = 1 then
Set f = fso.OpenTextFile(FileName, ForAppending)
f.Write TextStr
f.Close
WriteTxtFile = 1
Else
WriteTxtFile = -1
End if
End select
End Function